tinc-vpn.org Git - tinc/blob - test/unit/meson.build

   1 dep_cmocka = dependency('cmocka', required: opt_tests)
   2 if not dep_cmocka.found()
   3   subdir_done()
   4 endif
   5
   6 can_wrap = cc.has_link_argument('-Wl,--wrap=func')
   7 if not can_wrap
   8   message('linker has no support for function wrapping, mocked tests will not run')
   9 endif
  10
  11 link_tinc = { 'lib': lib_tinc, 'dep': deps_tinc }
  12 link_tincd = { 'lib': lib_tincd, 'dep': deps_tincd }
  13
  14 # Test definition format:
  15 #
  16 # 'free-form test name': {
  17 #   'code': 'test1.c',      // or ['test1.c', 'test1_util.c']
  18 #   'mock': ['foo', 'bar'], // list of functions to mock (default: empty)
  19 #   'link': link_tinc,      // which binary to link with (default: tincd)
  20 #   'fail': true,           // whether the test should fail (default: false)
  21 # }
  22
  23 tests = {
  24   'random': {
  25     'code': 'test_random.c',
  26   },
  27   'random_noinit': {
  28     'code': 'test_random_noinit.c',
  29     'fail': true,
  30   },
  31   'net': {
  32     'code': 'test_net.c',
  33     'mock': ['execute_script', 'environment_init', 'environment_exit'],
  34   },
  35   'subnet': {
  36     'code': 'test_subnet.c',
  37   },
  38   'protocol': {
  39     'code': 'test_protocol.c',
  40   },
  41   'splay_tree': {
  42     'code': 'test_splay_tree.c',
  43     'link': link_tinc,
  44   },
  45 }
  46
  47 env = ['CMOCKA_MESSAGE_OUTPUT=TAP']
  48
  49 foreach test, data : tests
  50   args = ld_flags
  51
  52   if can_wrap
  53     mocks = data.get('mock', [])
  54     if mocks.length() > 0
  55       args += ',--wrap='.join(['-Wl'] + mocks)
  56     endif
  57   endif
  58
  59   libs = data.get('link', link_tincd)
  60
  61   exe = executable(test,
  62                    sources: data['code'],
  63                    link_args: args,
  64                    dependencies: [libs['dep'], dep_cmocka],
  65                    link_with: libs['lib'],
  66                    implicit_include_directories: false,
  67                    include_directories: inc_conf,
  68                    build_by_default: false)
  69
  70   must_fail = data.get('fail', false)
  71
  72   test(test,
  73        exe,
  74        suite: 'unit',
  75        timeout: 60,
  76        protocol: must_fail ? 'exitcode' : 'tap',
  77        env: env,
  78        should_fail: must_fail)
  79 endforeach
  80