tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AM_SILENT_RULES([yes])
  11
  12 # Enable GNU extensions.
  13 # Define this here, not in acconfig's @TOP@ section, since definitions
  14 # in the latter don't make it into the configure-time tests.
  15 AC_GNU_SOURCE
  16 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC_C99
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_LN_S
  23
  24 AM_PROG_CC_C_O
  25
  26 dnl Check and set OS
  27
  28 AC_CANONICAL_HOST
  29
  30 case $host_os in
  31   *linux*)
  32     linux=true
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34   ;;
  35   *freebsd*)
  36     bsd=true
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38   ;;
  39   *darwin*)
  40     bsd=true
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42   ;;
  43   *solaris*)
  44     solaris=true
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46   ;;
  47   *openbsd*)
  48     bsd=true
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50   ;;
  51   *netbsd*)
  52     bsd=true
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54   ;;
  55   *dragonfly*)
  56     bsd=true
  57     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  58   ;;
  59   *bsd*)
  60     bsd=true
  61     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  62     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  63   ;;
  64   *cygwin*)
  65     cygwin=true
  66     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  67   ;;
  68   *mingw*)
  69     mingw=true
  70     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  71     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32 -liphlpapi"
  72     LDFLAGS="$LDFLAGS -static"
  73     CPPFLAGS="$CPPFLAGS -DMINIUPNP_STATICLIB"
  74   ;;
  75   *)
  76     AC_MSG_ERROR("Unknown operating system.")
  77   ;;
  78 esac
  79
  80 AC_ARG_ENABLE(uml,
  81   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  82   [ AS_IF([test "x$enable_uml" = "xyes"],
  83       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  84         uml=true
  85       ],
  86       [uml=false])
  87   ],
  88   [uml=false]
  89 )
  90
  91 AC_ARG_ENABLE(vde,
  92   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  93   [ AS_IF([test "x$enable_vde" = "xyes"],
  94       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  95         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  96         vde=true
  97       ],
  98       [vde=false])
  99   ],
 100   [vde=false]
 101 )
 102
 103 AC_ARG_ENABLE(tunemu,
 104   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 105   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 106       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 107         tunemu=true
 108       ],
 109       [tunemu=false])
 110   ],
 111   [tunemu=false]
 112 )
 113
 114 AC_ARG_WITH(windows2000,
 115   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 116   [ AS_IF([test "x$with_windows2000" = "xyes"],
 117       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 118   ]
 119 )
 120
 121 AC_ARG_WITH(systemd,
 122   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 123   [ systemd=true; systemd_path="$with_systemd" ],
 124   [ systemd=false ]
 125 )
 126
 127 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="/lib/systemd/system"],
 128       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 129
 130 AC_SUBST(systemd_path, $systemd_path)
 131
 132 AM_CONDITIONAL(LINUX, test "$linux" = true)
 133 AM_CONDITIONAL(BSD, test "$bsd" = true)
 134 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 135 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 136 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 137 AM_CONDITIONAL(UML, test "$uml" = true)
 138 AM_CONDITIONAL(VDE, test "$vde" = true)
 139 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 140 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 141
 142 AC_CACHE_SAVE
 143
 144 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 145 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 146
 147 dnl Compiler hardening flags
 148 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 149
 150 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 151 AS_IF([test "x$enable_hardening" != "xno"],
 152   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 153    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 154    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 155    case $host_os in
 156      *mingw*)
 157        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 158        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 159        ;;
 160      *)
 161        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 162        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 163        ;;
 164    esac
 165    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 166    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 167   ]
 168 );
 169
 170 dnl Checks for header files.
 171 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 172
 173 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h getopt.h])
 174 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 175   [], [], [#include "$srcdir/src/have.h"]
 176 )
 177 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 178   [], [], [#include "$srcdir/src/have.h"]
 179 )
 180 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 181   [], [], [#include "$srcdir/src/have.h"]
 182 )
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 tinc_ATTRIBUTE(__malloc__)
 186 tinc_ATTRIBUTE(__warn_unused_result__)
 187
 188 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 189   [#include "$srcdir/src/have.h"]
 190 )
 191
 192 dnl Checks for library functions.
 193 AC_TYPE_SIGNAL
 194 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork gettimeofday mlockall putenv random recvmmsg select strdup strsignal nanosleep unsetenv vsyslog devname fdevname],
 195   [], [], [#include "$srcdir/src/have.h"]
 196 )
 197
 198 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 199 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 200
 201 dnl Support for SunOS
 202
 203 AC_CHECK_FUNC(socket, [], [
 204   AC_CHECK_LIB(socket, connect)
 205 ])
 206 AC_CHECK_FUNC(gethostbyname, [], [
 207   AC_CHECK_LIB(nsl, gethostbyname)
 208 ])
 209
 210 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 211   [], [], [#include "$srcdir/src/have.h"]
 212 )
 213
 214 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 215   #include <netinet/in.h>
 216   #include <resolv.h>
 217 ])
 218
 219 AC_CACHE_SAVE
 220
 221 AC_ARG_ENABLE(legacy-protocol,
 222   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 223   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 224     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 225   ]
 226 )
 227
 228 dnl These are defined in files in m4/
 229
 230 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 231 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 232
 233 tinc_CURSES
 234 tinc_READLINE
 235 tinc_ZLIB
 236 tinc_LZO
 237
 238 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 239       [AS_IF([test -n "$with_libgcrypt"],
 240              [gcrypt=true; tinc_LIBGCRYPT],
 241              [openssl=true; tinc_OPENSSL])
 242       ]
 243 )
 244
 245 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 246 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 247
 248 tinc_MINIUPNPC
 249 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 250
 251 dnl Check if support for jumbograms is requested
 252 AC_ARG_ENABLE(jumbograms,
 253   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 254   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 255       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 256   ]
 257 )
 258
 259 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile gui/Makefile test/Makefile systemd/Makefile])
 260
 261 AC_OUTPUT