tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22
  23 AM_PROG_CC_C_O
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     linux=true
  32     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  33   ;;
  34   *freebsd*)
  35     bsd=true
  36     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  37   ;;
  38   *darwin*)
  39     bsd=true
  40     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  41   ;;
  42   *solaris*)
  43     solaris=true
  44     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  45   ;;
  46   *openbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  49   ;;
  50   *netbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  53   ;;
  54   *dragonfly*)
  55     bsd=true
  56     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  57   ;;
  58   *bsd*)
  59     bsd=true
  60     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62   ;;
  63   *cygwin*)
  64     cygwin=true
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_ENABLE(uml,
  78   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  79   [ AS_IF([test "x$enable_uml" = "xyes"],
  80       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  81         uml=true
  82       ],
  83       [uml=false])
  84   ],
  85   [uml=false]
  86 )
  87
  88 AC_ARG_ENABLE(vde,
  89   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  90   [ AS_IF([test "x$enable_vde" = "xyes"],
  91       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  92         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  93         vde=true
  94       ],
  95       [vde=false])
  96   ],
  97   [vde=false]
  98 )
  99
 100 AC_ARG_ENABLE(tunemu,
 101   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 102   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 103       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 104         tunemu=true
 105       ],
 106       [tunemu=false])
 107   ],
 108   [tunemu=false]
 109 )
 110
 111 AC_ARG_WITH(windows2000,
 112   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 113   [ AS_IF([test "x$with_windows2000" = "xyes"],
 114       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 115   ]
 116 )
 117
 118 AC_ARG_WITH(systemd,
 119   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 120   [ systemd=true; systemd_path="$with_systemd" ],
 121   [ systemd=false ]
 122 )
 123
 124 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="/lib/systemd/system"],
 125       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 126
 127 AC_SUBST(systemd_path, $systemd_path)
 128
 129 AM_CONDITIONAL(LINUX, test "$linux" = true)
 130 AM_CONDITIONAL(BSD, test "$bsd" = true)
 131 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 132 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 133 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 134 AM_CONDITIONAL(UML, test "$uml" = true)
 135 AM_CONDITIONAL(VDE, test "$vde" = true)
 136 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 137 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 138
 139 AC_CACHE_SAVE
 140
 141 if test -d /sw/include ; then
 142   CPPFLAGS="$CPPFLAGS -I/sw/include"
 143 fi
 144 if test -d /sw/lib ; then
 145   LIBS="$LIBS -L/sw/lib"
 146 fi
 147
 148 dnl Compiler hardening flags
 149 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 150
 151 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 152 AS_IF([test "x$enable_hardening" != "xno"],
 153   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 154    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 155    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 156    case $host_os in
 157      *mingw*)
 158        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 159        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 160        ;;
 161      *)
 162        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 163        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 164        ;;
 165    esac
 166    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 167    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 168   ]
 169 );
 170
 171 dnl Checks for header files.
 172 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 173
 174 AC_HEADER_STDC
 175 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 176 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 177   [], [], [#include "$srcdir/src/have.h"]
 178 )
 179 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 180   [], [], [#include "$srcdir/src/have.h"]
 181 )
 182 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 183   [], [], [#include "$srcdir/src/have.h"]
 184 )
 185
 186 dnl Checks for typedefs, structures, and compiler characteristics.
 187 AC_C_CONST
 188 AC_C_VOLATILE
 189 AC_TYPE_PID_T
 190 AC_TYPE_SIZE_T
 191 AC_HEADER_TIME
 192 AC_STRUCT_TM
 193
 194 tinc_ATTRIBUTE(__malloc__)
 195 tinc_ATTRIBUTE(__warn_unused_result__)
 196
 197 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 198   [#include "$srcdir/src/have.h"]
 199 )
 200
 201 dnl Checks for library functions.
 202 AC_TYPE_SIGNAL
 203 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 204   [], [], [#include "$srcdir/src/have.h"]
 205 )
 206
 207 dnl Support for SunOS
 208
 209 AC_CHECK_FUNC(socket, [], [
 210   AC_CHECK_LIB(socket, connect)
 211 ])
 212 AC_CHECK_FUNC(gethostbyname, [], [
 213   AC_CHECK_LIB(nsl, gethostbyname)
 214 ])
 215
 216 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 217   [], [], [#include "$srcdir/src/have.h"]
 218 )
 219
 220 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 221   #include <netinet/in.h>
 222   #include <resolv.h>
 223 ])
 224
 225 AC_CACHE_SAVE
 226
 227 AC_ARG_ENABLE(legacy-protocol,
 228   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 229   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 230     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 231   ]
 232 )
 233
 234 dnl These are defined in files in m4/
 235
 236 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 237 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 238
 239 tinc_CURSES
 240 tinc_READLINE
 241 tinc_ZLIB
 242 tinc_LZO
 243
 244 if test "x$enable_legacy_protocol" != "xno"; then
 245         if test -n "$with_libgcrypt"; then
 246                 gcrypt=true
 247                 tinc_LIBGCRYPT
 248         else
 249                 openssl=true
 250                 tinc_OPENSSL
 251         fi
 252 fi
 253
 254 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 255 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 256
 257 dnl Check if support for jumbograms is requested
 258 AC_ARG_ENABLE(jumbograms,
 259   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 260   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 261       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 262   ]
 263 )
 264
 265 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile gui/Makefile test/Makefile systemd/Makefile])
 266
 267 AC_OUTPUT