dnl Process this file with autoconf to produce a configure script.

dnl $Id: configure.in,v 1.13.2.14 2000/11/07 22:33:33 guus Exp $

AC_INIT(src/tincd.c)
AM_INIT_AUTOMAKE(tinc, 1.0pre3)
AM_CONFIG_HEADER(config.h)

dnl Include the macros from the m4/ directory
AM_ACLOCAL_INCLUDE(m4)

# Enable GNU extensions.
# Define this here, not in acconfig's @TOP@ section, since definitions
# in the latter don't make it into the configure-time tests.
AC_DEFINE([_GNU_SOURCE], [__USE_BSD])

ALL_LINGUAS="es nl"

dnl Checks for programs.
AC_PROG_CC
AC_PROG_CPP
AC_PROG_GCC_TRADITIONAL
AC_PROG_AWK
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
jm_PERL
AM_PROG_LIBTOOL

AC_ISC_POSIX

dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h syslog.h unistd.h sys/time.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_HEADER_TIME
AC_STRUCT_TM

dnl Checks for library functions.
AC_FUNC_MEMCMP
AC_FUNC_ALLOCA
AC_TYPE_SIGNAL
AC_CHECK_FUNCS(ftime socket select strtol strerror flock)
jm_FUNC_MALLOC
jm_FUNC_REALLOC

AM_GNU_GETTEXT

AC_CHECK_LIB(dl, dlopen, [
  LIBS="$LIBS -ldl"
])


dnl Crypto stuff

libcrypto=none
AC_CHECK_LIB(crypto, SHA1_version, [
  libcrypto=yes
])

if test $libcrypto = none; then
  AC_MSG_ERROR(It seems like OpenSSL is not installed on this system.)
else
  LIBS="$LIBS -lcrypto"
fi


dnl Support for SunOS

AC_CHECK_FUNC(socket, [], [
  AC_CHECK_LIB(socket, connect)
])
AC_CHECK_FUNC(gethostbyname, [], [
  AC_CHECK_LIB(nsl, gethostbyname)
])


dnl Check for TUN/TAP support in the kernel
tinc_TUNTAP

AC_OUTPUT([Makefile src/Makefile
doc/Makefile doc/es/Makefile intl/Makefile lib/Makefile
m4/Makefile po/Makefile.in redhat/Makefile debian/Makefile])