tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 origcflags="$CFLAGS"
   4
   5 AC_PREREQ(2.61)
   6 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AM_SILENT_RULES([yes])
  12
  13 # Enable GNU extensions.
  14 # Define this here, not in acconfig's @TOP@ section, since definitions
  15 # in the latter don't make it into the configure-time tests.
  16 AC_GNU_SOURCE
  17 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  18
  19 dnl Checks for programs.
  20 AC_PROG_CC_C99
  21 AC_PROG_CPP
  22 AC_PROG_INSTALL
  23 AM_PROG_CC_C_O
  24
  25 dnl Check whether to enable code coverage testing, and if so, clear the default CFLAGS.
  26 AX_CODE_COVERAGE
  27 AS_IF([test "x$enable_code_coverage" = "xyes" -a "x$origcflags" = "x"], [CFLAGS=""])
  28
  29 dnl Check and set OS
  30
  31 AC_CANONICAL_HOST
  32
  33 case $host_os in
  34   *linux*)
  35     linux=true
  36     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  37   ;;
  38   *freebsd*)
  39     bsd=true
  40     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  41   ;;
  42   *darwin*)
  43     bsd=true
  44     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  45   ;;
  46   *solaris*)
  47     solaris=true
  48     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  49   ;;
  50   *openbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  53   ;;
  54   *netbsd*)
  55     bsd=true
  56     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  57   ;;
  58   *dragonfly*)
  59     bsd=true
  60     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  61   ;;
  62   *bsd*)
  63     bsd=true
  64     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  65     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  66   ;;
  67   *cygwin*)
  68     cygwin=true
  69     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  70   ;;
  71   *mingw*)
  72     mingw=true
  73     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  74     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32 -liphlpapi"
  75     LDFLAGS="$LDFLAGS -static"
  76     CPPFLAGS="$CPPFLAGS -DMINIUPNP_STATICLIB"
  77   ;;
  78   *)
  79     AC_MSG_ERROR("Unknown operating system.")
  80   ;;
  81 esac
  82
  83 AC_ARG_ENABLE(uml,
  84   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  85   [ AS_IF([test "x$enable_uml" = "xyes"],
  86       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  87         uml=true
  88       ],
  89       [uml=false])
  90   ],
  91   [uml=false]
  92 )
  93
  94 AC_ARG_ENABLE(vde,
  95   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  96   [ AS_IF([test "x$enable_vde" = "xyes"],
  97       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  98         AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"], [AC_MSG_ERROR([VDE plug depends on libdl.]); break])
  99         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
 100         vde=true
 101       ],
 102       [vde=false])
 103   ],
 104   [vde=false]
 105 )
 106
 107 AC_ARG_ENABLE(tunemu,
 108   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 109   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 110       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 111         tunemu=true
 112       ],
 113       [tunemu=false])
 114   ],
 115   [tunemu=false]
 116 )
 117
 118 AC_ARG_WITH(systemd,
 119   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 120   [ systemd=true; systemd_path="$with_systemd" ],
 121   [ systemd=false ]
 122 )
 123
 124 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="\${libdir}/systemd/system"],
 125       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 126
 127 AC_SUBST(systemd_path, $systemd_path)
 128
 129 AM_CONDITIONAL(LINUX, test "$linux" = true)
 130 AM_CONDITIONAL(BSD, test "$bsd" = true)
 131 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 132 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 133 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 134 AM_CONDITIONAL(UML, test "$uml" = true)
 135 AM_CONDITIONAL(VDE, test "$vde" = true)
 136 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 137 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 138
 139 AC_CACHE_SAVE
 140
 141 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 142 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 143
 144 dnl Compiler hardening flags
 145 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 146
 147 AX_CFLAGS_WARN_ALL(CFLAGS)
 148
 149 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 150 AS_IF([test "x$enable_hardening" != "xno"],
 151   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 152    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 153    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 154    case $host_os in
 155      *mingw*)
 156        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 157        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 158        ;;
 159      *)
 160        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 161        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 162        ;;
 163    esac
 164    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 165    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 166   ]
 167 );
 168
 169 dnl Checks for header files.
 170 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 171
 172 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h getopt.h])
 173 AC_CHECK_HEADERS([net/if.h net/if_types.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 174   [], [], [#include "$srcdir/src/have.h"]
 175 )
 176 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 177   [], [], [#include "$srcdir/src/have.h"]
 178 )
 179 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 180   [], [], [#include "$srcdir/src/have.h"]
 181 )
 182
 183 dnl Checks for typedefs, structures, and compiler characteristics.
 184 tinc_ATTRIBUTE(__malloc__)
 185 tinc_ATTRIBUTE(__nonnull__)
 186 tinc_ATTRIBUTE(__warn_unused_result__)
 187
 188 AC_CHECK_TYPES([struct ether_header, struct arphdr, struct ether_arp, struct ip, struct icmp, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 189   [#include "$srcdir/src/have.h"]
 190 )
 191
 192 dnl Checks for library functions.
 193 AC_TYPE_SIGNAL
 194 AC_CHECK_FUNCS([asprintf daemon fchmod flock fork gettimeofday mlockall putenv recvmmsg strsignal nanosleep unsetenv vsyslog devname fdevname],
 195   [], [], [#include "$srcdir/src/have.h"]
 196 )
 197
 198 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 199 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 200
 201 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 202   #include <netinet/in.h>
 203   #include <resolv.h>
 204 ])
 205
 206 dnl Operating system specific checks
 207 case $host_os in
 208   *linux*)
 209     AC_CHECK_HEADERS([linux/if_tun.h],
 210       [], [AC_MSG_ERROR([Required header file missng])], [#include "$srcdir/src/have.h"]
 211     )
 212   ;;
 213   *bsd*|*dragonfly*|*darwin*)
 214     AC_CHECK_HEADERS([net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h],
 215       [], [], [#include "$srcdir/src/have.h"]
 216     )
 217   ;;
 218   *solaris*)
 219     AC_CHECK_FUNC(socket, [], [AC_CHECK_LIB(socket, connect)])
 220   ;;
 221   *)
 222   ;;
 223 esac
 224
 225 AC_CACHE_SAVE
 226
 227 AC_ARG_ENABLE(legacy-protocol,
 228   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 229   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 230     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 231   ]
 232 )
 233
 234 dnl These are defined in files in m4/
 235
 236 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 237 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 238
 239 tinc_CURSES
 240 tinc_READLINE
 241 tinc_ZLIB
 242 tinc_LZO
 243
 244 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 245       [AS_IF([test -n "$with_libgcrypt"],
 246              [gcrypt=true; tinc_LIBGCRYPT],
 247              [openssl=true; tinc_OPENSSL])
 248       ]
 249 )
 250
 251 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 252 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 253
 254 tinc_MINIUPNPC
 255 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 256
 257 dnl Check if support for jumbograms is requested
 258 AC_ARG_ENABLE(jumbograms,
 259   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 260   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 261       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 262   ]
 263 )
 264
 265 dnl Ensure runstatedir is set if we are using a version of autoconf that does not support it
 266 if test "x$runstatedir" = "x"; then
 267   AC_SUBST([runstatedir], ['${localstatedir}/run'])
 268 fi
 269
 270 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile test/Makefile systemd/Makefile bash_completion.d/Makefile])
 271
 272 AC_OUTPUT