tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 origcflags="$CFLAGS"
   4
   5 AC_PREREQ(2.69)
   6 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AM_SILENT_RULES([yes])
  12
  13 AC_USE_SYSTEM_EXTENSIONS
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CC_STDC
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AM_PROG_CC_C_O
  21
  22 dnl Check whether to enable code coverage testing, and if so, clear the default CFLAGS.
  23 AX_CODE_COVERAGE
  24 AS_IF([test "x$enable_code_coverage" = "xyes" -a "x$origcflags" = "x"], [CFLAGS=""])
  25
  26 dnl Check and set OS
  27
  28 AC_CANONICAL_HOST
  29
  30 case $host_os in
  31   *linux*)
  32     linux=true
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34   ;;
  35   *freebsd*)
  36     bsd=true
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38   ;;
  39   *darwin*)
  40     bsd=true
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42   ;;
  43   *solaris*)
  44     solaris=true
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46   ;;
  47   *openbsd*)
  48     bsd=true
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50   ;;
  51   *netbsd*)
  52     bsd=true
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54   ;;
  55   *dragonfly*)
  56     bsd=true
  57     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  58   ;;
  59   *bsd*)
  60     bsd=true
  61     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  62     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  63   ;;
  64   *cygwin*)
  65     AC_MSG_ERROR("Cygwin is no longer supported. Use MinGW to build native Windows binaries.")
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32 -liphlpapi"
  71     LDFLAGS="$LDFLAGS -static"
  72     CPPFLAGS="$CPPFLAGS -DMINIUPNP_STATICLIB"
  73   ;;
  74   *)
  75     AC_MSG_ERROR("Unknown operating system.")
  76   ;;
  77 esac
  78
  79 AC_ARG_ENABLE(uml,
  80   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  81   [ AS_IF([test "x$enable_uml" = "xyes"],
  82       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  83         uml=true
  84       ],
  85       [uml=false])
  86   ],
  87   [uml=false]
  88 )
  89
  90 AC_ARG_ENABLE(vde,
  91   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  92   [ AS_IF([test "x$enable_vde" = "xyes"],
  93       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  94         AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"], [AC_MSG_ERROR([VDE plug depends on libdl.]); break])
  95         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  96         vde=true
  97       ],
  98       [vde=false])
  99   ],
 100   [vde=false]
 101 )
 102
 103 AC_ARG_ENABLE(tunemu,
 104   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 105   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 106       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 107         tunemu=true
 108       ],
 109       [tunemu=false])
 110   ],
 111   [tunemu=false]
 112 )
 113
 114 AC_ARG_WITH(systemd,
 115   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 116   [ systemd=true; systemd_path="$with_systemd" ],
 117   [ systemd=false ]
 118 )
 119
 120 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="\${libdir}/systemd/system"],
 121       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 122
 123 AC_SUBST(systemd_path, $systemd_path)
 124
 125 AM_CONDITIONAL(LINUX, test "$linux" = true)
 126 AM_CONDITIONAL(BSD, test "$bsd" = true)
 127 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 128 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 129 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 130 AM_CONDITIONAL(UML, test "$uml" = true)
 131 AM_CONDITIONAL(VDE, test "$vde" = true)
 132 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 133 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 134 AM_CONDITIONAL(WITH_LEGACY_PROTOCOL, test "x$enable_legacy_protocol" != "xno")
 135
 136 AC_CACHE_SAVE
 137
 138 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 139 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 140
 141 dnl Compiler hardening flags
 142 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 143
 144 AX_CFLAGS_WARN_ALL(CFLAGS)
 145
 146 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 147 AS_IF([test "x$enable_hardening" != "xno"],
 148   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 149    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 150    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 151    case $host_os in
 152      *mingw*)
 153        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 154        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 155        ;;
 156      *)
 157        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 158        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 159        ;;
 160    esac
 161    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 162    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 163   ]
 164 );
 165
 166 dnl Checks for header files.
 167 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 168
 169 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h getopt.h stddef.h])
 170 AC_CHECK_HEADERS([net/if.h net/if_types.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 171   [], [], [#include "$srcdir/src/have.h"]
 172 )
 173 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 174   [], [], [#include "$srcdir/src/have.h"]
 175 )
 176 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 177   [], [], [#include "$srcdir/src/have.h"]
 178 )
 179
 180 dnl Checks for typedefs, structures, and compiler characteristics.
 181 tinc_ATTRIBUTE(__malloc__)
 182 tinc_ATTRIBUTE(__nonnull__)
 183 tinc_ATTRIBUTE(__warn_unused_result__)
 184
 185 AC_CHECK_TYPES([struct ether_header, struct arphdr, struct ether_arp, struct ip, struct icmp, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 186   [#include "$srcdir/src/have.h"]
 187 )
 188
 189 dnl Checks for library functions.
 190 AC_CHECK_FUNCS([asprintf daemon fchmod flock fork gettimeofday mlockall putenv recvmmsg strsignal nanosleep unsetenv vsyslog devname fdevname],
 191   [], [], [#include "$srcdir/src/have.h"]
 192 )
 193
 194 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 195 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 196
 197 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 198   #include <netinet/in.h>
 199   #include <resolv.h>
 200 ])
 201
 202 dnl Operating system specific checks
 203 case $host_os in
 204   *linux*)
 205     AC_CHECK_HEADERS([linux/if_tun.h],
 206       [], [AC_MSG_ERROR([Required header file missng])], [#include "$srcdir/src/have.h"]
 207     )
 208   ;;
 209   *bsd*|*dragonfly*|*darwin*)
 210     AC_CHECK_HEADERS([net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h],
 211       [], [], [#include "$srcdir/src/have.h"]
 212     )
 213   ;;
 214   *solaris*)
 215     AC_CHECK_FUNC(socket, [], [AC_CHECK_LIB(socket, connect)])
 216   ;;
 217   *)
 218   ;;
 219 esac
 220
 221 AC_CACHE_SAVE
 222
 223 AC_ARG_ENABLE(legacy-protocol,
 224   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 225   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 226     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 227   ]
 228 )
 229
 230 dnl These are defined in files in m4/
 231
 232 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 233 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 234
 235 tinc_CURSES
 236 tinc_READLINE
 237 tinc_ZLIB
 238 tinc_LZO
 239 tinc_LZ4
 240
 241 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 242       [AS_IF([test -n "$with_libgcrypt"],
 243              [gcrypt=true; tinc_LIBGCRYPT],
 244              [openssl=true; tinc_OPENSSL])
 245       ]
 246 )
 247
 248 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 249 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 250
 251 tinc_MINIUPNPC
 252 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 253
 254 dnl Check if support for jumbograms is requested
 255 AC_ARG_ENABLE(jumbograms,
 256   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 257   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 258       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 259   ]
 260 )
 261
 262 dnl Ensure runstatedir is set if we are using a version of autoconf that does not support it
 263 if test "x$runstatedir" = "x"; then
 264   AC_SUBST([runstatedir], ['${localstatedir}/run'])
 265 fi
 266
 267 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile test/Makefile test/testlib.sh systemd/Makefile bash_completion.d/Makefile])
 268
 269 AC_OUTPUT