tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AC_GNU_SOURCE
   7 AM_INIT_AUTOMAKE([std-options subdir-objects -Wall])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 # Enable GNU extensions.
  12 # Define this here, not in acconfig's @TOP@ section, since definitions
  13 # in the latter don't make it into the configure-time tests.
  14 AC_GNU_SOURCE
  15 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  16
  17 dnl Checks for programs.
  18 AC_PROG_CC_C99
  19 AC_PROG_CPP
  20 AC_PROG_INSTALL
  21 AC_PROG_LN_S
  22
  23 AM_PROG_CC_C_O
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     linux=true
  32     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  33   ;;
  34   *freebsd*)
  35     bsd=true
  36     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  37   ;;
  38   *darwin*)
  39     bsd=true
  40     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  41   ;;
  42   *solaris*)
  43     solaris=true
  44     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  45   ;;
  46   *openbsd*)
  47     bsd=true
  48     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  49   ;;
  50   *netbsd*)
  51     bsd=true
  52     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  53   ;;
  54   *dragonfly*)
  55     bsd=true
  56     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  57   ;;
  58   *bsd*)
  59     bsd=true
  60     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  61     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  62   ;;
  63   *cygwin*)
  64     cygwin=true
  65     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_ENABLE(uml,
  78   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  79   [ AS_IF([test "x$enable_uml" = "xyes"],
  80       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  81         uml=true
  82       ],
  83       [uml=false])
  84   ],
  85   [uml=false]
  86 )
  87
  88 AC_ARG_ENABLE(vde,
  89   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  90   [ AS_IF([test "x$enable_vde" = "xyes"],
  91       [ AC_CHECK_HEADERS(libvdeplug_dyn.h, [], [AC_MSG_ERROR([VDE plug header files not found.]); break])
  92         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
  93         vde=true
  94       ],
  95       [vde=false])
  96   ],
  97   [vde=false]
  98 )
  99
 100 AC_ARG_ENABLE(tunemu,
 101   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 102   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 103       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 104         tunemu=true
 105       ],
 106       [tunemu=false])
 107   ],
 108   [tunemu=false]
 109 )
 110
 111 AC_ARG_WITH(windows2000,
 112   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
 113   [ AS_IF([test "x$with_windows2000" = "xyes"],
 114       [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])])
 115   ]
 116 )
 117
 118 AC_ARG_WITH(systemd,
 119   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 120   [ systemd=true; systemd_path="$with_systemd" ],
 121   [ systemd=false ]
 122 )
 123
 124 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="/lib/systemd/system"],
 125       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 126
 127 AC_SUBST(systemd_path, $systemd_path)
 128
 129 AM_CONDITIONAL(LINUX, test "$linux" = true)
 130 AM_CONDITIONAL(BSD, test "$bsd" = true)
 131 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 132 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 133 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 134 AM_CONDITIONAL(UML, test "$uml" = true)
 135 AM_CONDITIONAL(VDE, test "$vde" = true)
 136 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 137 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 138
 139 AC_CACHE_SAVE
 140
 141 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 142 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 143
 144 dnl Compiler hardening flags
 145 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 146
 147 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 148 AS_IF([test "x$enable_hardening" != "xno"],
 149   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 150    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"])
 151    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"])
 152    case $host_os in
 153      *mingw*)
 154        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 155        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 156        ;;
 157      *)
 158        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 159        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 160        ;;
 161    esac
 162    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 163    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 164   ]
 165 );
 166
 167 dnl Checks for header files.
 168 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 169
 170 AC_HEADER_STDC
 171 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 172 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h time.h netpacket/packet.h],
 173   [], [], [#include "$srcdir/src/have.h"]
 174 )
 175 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 176   [], [], [#include "$srcdir/src/have.h"]
 177 )
 178 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 179   [], [], [#include "$srcdir/src/have.h"]
 180 )
 181
 182 dnl Checks for typedefs, structures, and compiler characteristics.
 183 AC_C_CONST
 184 AC_C_VOLATILE
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_HEADER_TIME
 188 AC_STRUCT_TM
 189
 190 tinc_ATTRIBUTE(__malloc__)
 191 tinc_ATTRIBUTE(__warn_unused_result__)
 192
 193 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 194   [#include "$srcdir/src/have.h"]
 195 )
 196
 197 dnl Checks for library functions.
 198 AC_TYPE_SIGNAL
 199 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system time usleep unsetenv vsyslog writev],
 200   [], [], [#include "$srcdir/src/have.h"]
 201 )
 202
 203 dnl Support for SunOS
 204
 205 AC_CHECK_FUNC(socket, [], [
 206   AC_CHECK_LIB(socket, connect)
 207 ])
 208 AC_CHECK_FUNC(gethostbyname, [], [
 209   AC_CHECK_LIB(nsl, gethostbyname)
 210 ])
 211
 212 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 213   [], [], [#include "$srcdir/src/have.h"]
 214 )
 215
 216 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 217   #include <netinet/in.h>
 218   #include <resolv.h>
 219 ])
 220
 221 AC_CACHE_SAVE
 222
 223 AC_ARG_ENABLE(legacy-protocol,
 224   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 225   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 226     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 227   ]
 228 )
 229
 230 dnl These are defined in files in m4/
 231
 232 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 233 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 234
 235 tinc_CURSES
 236 tinc_READLINE
 237 tinc_ZLIB
 238 tinc_LZO
 239
 240 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 241       [AS_IF([test -n "$with_libgcrypt"],
 242              [gcrypt=true; tinc_LIBGCRYPT],
 243              [openssl=true; tinc_OPENSSL])
 244       ]
 245 )
 246
 247 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 248 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 249
 250 tinc_MINIUPNPC
 251 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 252
 253 dnl Check if support for jumbograms is requested
 254 AC_ARG_ENABLE(jumbograms,
 255   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 256   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 257       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 258   ]
 259 )
 260
 261 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile gui/Makefile test/Makefile systemd/Makefile])
 262
 263 AC_OUTPUT