tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 origcflags="$CFLAGS"
   4
   5 AC_PREREQ(2.69)
   6 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AM_SILENT_RULES([yes])
  12
  13 AC_USE_SYSTEM_EXTENSIONS
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CC_STDC
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AM_PROG_CC_C_O
  21
  22 dnl Check whether to enable code coverage testing, and if so, clear the default CFLAGS.
  23 AX_CODE_COVERAGE
  24 AS_IF([test "x$enable_code_coverage" = "xyes" -a "x$origcflags" = "x"], [CFLAGS=""])
  25
  26 dnl Check and set OS
  27
  28 AC_CANONICAL_HOST
  29
  30 case $host_os in
  31   *linux*)
  32     linux=true
  33     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  34   ;;
  35   *freebsd*)
  36     bsd=true
  37     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  38   ;;
  39   *darwin*)
  40     bsd=true
  41     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  42   ;;
  43   *solaris*)
  44     solaris=true
  45     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  46   ;;
  47   *openbsd*)
  48     bsd=true
  49     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  50   ;;
  51   *netbsd*)
  52     bsd=true
  53     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  54   ;;
  55   *dragonfly*)
  56     bsd=true
  57     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  58   ;;
  59   *bsd*)
  60     bsd=true
  61     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  62     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  63   ;;
  64   *cygwin*)
  65     AC_MSG_ERROR("Cygwin is no longer supported. Use MinGW to build native Windows binaries.")
  66   ;;
  67   *mingw*)
  68     mingw=true
  69     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32 -liphlpapi"
  71     LDFLAGS="$LDFLAGS -static"
  72     CPPFLAGS="$CPPFLAGS -DMINIUPNP_STATICLIB"
  73   ;;
  74   *)
  75     AC_MSG_ERROR("Unknown operating system.")
  76   ;;
  77 esac
  78
  79 AC_ARG_ENABLE(uml,
  80   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  81   [ AS_IF([test "x$enable_uml" = "xyes"],
  82       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  83         uml=true
  84       ],
  85       [uml=false])
  86   ],
  87   [uml=false]
  88 )
  89
  90 AC_ARG_ENABLE(vde,
  91   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  92   [ AS_IF([test "x$enable_vde" = "xyes"],
  93       [ AC_CHECK_HEADERS(libvdeplug.h,
  94         [AC_CHECK_LIB(vdeplug, vde_close,
  95                       [LIBS="$LIBS -lvdeplug"],
  96                       [AC_MSG_ERROR("VDE plug library files not found.")]
  97         )],
  98         [AC_MSG_ERROR([VDE plug header files not found.]); break])
  99         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
 100         vde=true
 101       ],
 102       [vde=false])
 103   ],
 104   [vde=false]
 105 )
 106
 107 AC_ARG_ENABLE(tunemu,
 108   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 109   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 110       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 111         tunemu=true
 112       ],
 113       [tunemu=false])
 114   ],
 115   [tunemu=false]
 116 )
 117
 118 AC_ARG_WITH(systemd,
 119   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 120   [ systemd=true; systemd_path="$with_systemd" ],
 121   [ systemd=false ]
 122 )
 123
 124 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="\${libdir}/systemd/system"],
 125       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 126
 127 AC_SUBST(systemd_path, $systemd_path)
 128
 129 AM_CONDITIONAL(LINUX, test "$linux" = true)
 130 AM_CONDITIONAL(BSD, test "$bsd" = true)
 131 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 132 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 133 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 134 AM_CONDITIONAL(UML, test "$uml" = true)
 135 AM_CONDITIONAL(VDE, test "$vde" = true)
 136 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 137 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 138 AM_CONDITIONAL(WITH_LEGACY_PROTOCOL, test "x$enable_legacy_protocol" != "xno")
 139
 140 AC_CACHE_SAVE
 141
 142 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 143 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 144
 145 dnl Compiler hardening flags
 146 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 147
 148 AX_CFLAGS_WARN_ALL(CFLAGS)
 149
 150 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 151 AS_IF([test "x$enable_hardening" != "xno"],
 152   [AX_CHECK_COMPILE_FLAG([-DFORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -DFORTIFY_SOURCE=2"])
 153    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 154    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 155    case $host_os in
 156      *mingw*)
 157        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 158        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 159        ;;
 160      *)
 161        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 162        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 163        ;;
 164    esac
 165    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 166    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 167   ]
 168 );
 169
 170 dnl Checks for header files.
 171 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 172
 173 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h getopt.h stddef.h sys/epoll.h])
 174 AC_CHECK_HEADERS([net/if.h net/if_types.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 175   [], [], [#include "$srcdir/src/have.h"]
 176 )
 177 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 178   [], [], [#include "$srcdir/src/have.h"]
 179 )
 180 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 181   [], [], [#include "$srcdir/src/have.h"]
 182 )
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 tinc_ATTRIBUTE(__malloc__)
 186 tinc_ATTRIBUTE(__nonnull__)
 187 tinc_ATTRIBUTE(__warn_unused_result__)
 188
 189 AC_CHECK_TYPES([struct ether_header, struct arphdr, struct ether_arp, struct ip, struct icmp, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 190   [#include "$srcdir/src/have.h"]
 191 )
 192
 193 dnl Checks for library functions.
 194 AC_CHECK_FUNCS([asprintf daemon fchmod flock fork gettimeofday mlockall putenv recvmmsg strsignal nanosleep unsetenv vsyslog devname fdevname],
 195   [], [], [#include "$srcdir/src/have.h"]
 196 )
 197
 198 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 199 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 200
 201 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 202   #include <netinet/in.h>
 203   #include <resolv.h>
 204 ])
 205
 206 dnl Operating system specific checks
 207 case $host_os in
 208   *linux*)
 209     AC_CHECK_HEADERS([linux/if_tun.h],
 210       [], [AC_MSG_ERROR([Required header file missng])], [#include "$srcdir/src/have.h"]
 211     )
 212   ;;
 213   *bsd*|*dragonfly*|*darwin*)
 214     AC_CHECK_HEADERS([net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h],
 215       [], [], [#include "$srcdir/src/have.h"]
 216     )
 217   ;;
 218   *solaris*)
 219     AC_CHECK_FUNC(socket, [], [AC_CHECK_LIB(socket, connect)])
 220   ;;
 221   *)
 222   ;;
 223 esac
 224
 225 AC_CACHE_SAVE
 226
 227 AC_ARG_ENABLE(legacy-protocol,
 228   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 229   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 230     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 231   ]
 232 )
 233
 234 dnl These are defined in files in m4/
 235
 236 dnl AC_ARG_WITH(libgcrypt, AC_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 237 dnl AC_ARG_WITH(openssl, AC_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 238
 239 tinc_CURSES
 240 tinc_READLINE
 241 tinc_ZLIB
 242 tinc_LZO
 243 tinc_LZ4
 244
 245 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 246       [AS_IF([test -n "$with_libgcrypt"],
 247              [gcrypt=true; tinc_LIBGCRYPT],
 248              [openssl=true; tinc_OPENSSL])
 249       ]
 250 )
 251
 252 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 253 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 254
 255 tinc_MINIUPNPC
 256 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 257
 258 dnl Check if support for jumbograms is requested
 259 AC_ARG_ENABLE(jumbograms,
 260   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 261   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 262       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 263   ]
 264 )
 265
 266 dnl Ensure runstatedir is set if we are using a version of autoconf that does not support it
 267 if test "x$runstatedir" = "x"; then
 268   AC_SUBST([runstatedir], ['${localstatedir}/run'])
 269 fi
 270
 271 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile test/Makefile test/testlib.sh systemd/Makefile bash_completion.d/Makefile])
 272
 273 AC_OUTPUT