tinc-vpn.org Git - tinc/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 origcflags="$CFLAGS"
   4
   5 AC_PREREQ([2.69])
   6 AC_INIT([tinc], m4_esyscmd_s((git describe || echo UNKNOWN) | sed 's/release-//'))
   7 AC_CONFIG_SRCDIR([src/tincd.c])
   8 AM_INIT_AUTOMAKE([std-options subdir-objects nostdinc silent-rules -Wall])
   9 AC_CONFIG_HEADERS([config.h])
  10 AC_CONFIG_MACRO_DIR([m4])
  11 AM_SILENT_RULES([yes])
  12
  13 AC_USE_SYSTEM_EXTENSIONS
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AC_PROG_CC_C99
  18 AC_PROG_CPP
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21 AM_PROG_CC_C_O
  22
  23 dnl Check whether to enable code coverage testing, and if so, clear the default CFLAGS.
  24 AX_CODE_COVERAGE
  25 AS_IF([test "x$enable_code_coverage" = "xyes" -a "x$origcflags" = "x"], [CFLAGS=""])
  26
  27 dnl Check and set OS
  28
  29 AC_CANONICAL_HOST
  30
  31 case $host_os in
  32   *linux*)
  33     linux=true
  34     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  35   ;;
  36   *freebsd*)
  37     bsd=true
  38     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  39   ;;
  40   *darwin*)
  41     bsd=true
  42     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  43   ;;
  44   *solaris*)
  45     solaris=true
  46     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  47   ;;
  48   *openbsd*)
  49     bsd=true
  50     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  51   ;;
  52   *netbsd*)
  53     bsd=true
  54     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  55   ;;
  56   *dragonfly*)
  57     bsd=true
  58     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  59   ;;
  60   *bsd*)
  61     bsd=true
  62     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  63     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  64   ;;
  65   *cygwin*)
  66     AC_MSG_ERROR("Cygwin is no longer supported. Use MinGW to build native Windows binaries.")
  67   ;;
  68   *mingw*)
  69     mingw=true
  70     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  71     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32 -liphlpapi -lwinpthread"
  72     LDFLAGS="$LDFLAGS -static"
  73     CPPFLAGS="$CPPFLAGS -DMINIUPNP_STATICLIB"
  74   ;;
  75   *)
  76     AC_MSG_ERROR("Unknown operating system.")
  77   ;;
  78 esac
  79
  80 AC_ARG_ENABLE(uml,
  81   AS_HELP_STRING([--enable-uml], [enable support for User Mode Linux]),
  82   [ AS_IF([test "x$enable_uml" = "xyes"],
  83       [ AC_DEFINE(ENABLE_UML, 1, [Support for UML])
  84         uml=true
  85       ],
  86       [uml=false])
  87   ],
  88   [uml=false]
  89 )
  90
  91 AC_ARG_ENABLE(vde,
  92   AS_HELP_STRING([--enable-vde], [enable support for Virtual Distributed Ethernet]),
  93   [ AS_IF([test "x$enable_vde" = "xyes"],
  94       [ AC_CHECK_HEADERS(libvdeplug.h,
  95         [AC_CHECK_LIB(vdeplug, vde_close,
  96                       [LIBS="$LIBS -lvdeplug"],
  97                       [AC_MSG_ERROR("VDE plug library files not found.")]
  98         )],
  99         [AC_MSG_ERROR([VDE plug header files not found.]); break])
 100         AC_DEFINE(ENABLE_VDE, 1, [Support for VDE])
 101         vde=true
 102       ],
 103       [vde=false])
 104   ],
 105   [vde=false]
 106 )
 107
 108 AC_ARG_ENABLE(tunemu,
 109   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
 110   [ AS_IF([test "x$enable_tunemu" = "xyes"],
 111       [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
 112         tunemu=true
 113       ],
 114       [tunemu=false])
 115   ],
 116   [tunemu=false]
 117 )
 118
 119 AC_ARG_WITH(systemd,
 120   AS_HELP_STRING([--with-systemd@<:@=DIR@:>@], [install systemd service files @<:@to DIR if specified@:>@]),
 121   [ systemd=true; systemd_path="$with_systemd" ],
 122   [ systemd=false ]
 123 )
 124
 125 AS_IF([test "x$with_systemd" = "xyes"], [systemd_path="\${libdir}/systemd/system"],
 126       [AS_IF([test "x$with_systemd" = "xno"], [systemd=false])])
 127
 128 AC_SUBST(systemd_path, $systemd_path)
 129
 130 AM_CONDITIONAL(LINUX, test "$linux" = true)
 131 AM_CONDITIONAL(BSD, test "$bsd" = true)
 132 AM_CONDITIONAL(SOLARIS, test "$solaris" = true)
 133 AM_CONDITIONAL(MINGW, test "$mingw" = true)
 134 AM_CONDITIONAL(CYGWIN, test "$cygwin" = true)
 135 AM_CONDITIONAL(UML, test "$uml" = true)
 136 AM_CONDITIONAL(VDE, test "$vde" = true)
 137 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
 138 AM_CONDITIONAL(WITH_SYSTEMD, test "$systemd" = true)
 139 AM_CONDITIONAL(WITH_LEGACY_PROTOCOL, test "x$enable_legacy_protocol" != "xno")
 140
 141 AC_CACHE_SAVE
 142
 143 AS_IF([test -d /sw/include], [CPPFLAGS="$CPPFLAGS -I/sw/include"])
 144 AS_IF([test -d /sw/lib], [LIBS="$LIBS -L/sw/lib"])
 145
 146 dnl Checks for header files.
 147 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 148
 149 AC_CHECK_HEADERS([syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/un.h sys/wait.h netdb.h arpa/inet.h dirent.h getopt.h stddef.h sys/epoll.h])
 150 AC_CHECK_HEADERS([net/if.h net/if_types.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h netpacket/packet.h],
 151   [], [], [#include "$srcdir/src/have.h"]
 152 )
 153 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h resolv.h],
 154   [], [], [#include "$srcdir/src/have.h"]
 155 )
 156 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 157   [], [], [#include "$srcdir/src/have.h"]
 158 )
 159
 160 dnl Checks for typedefs, structures, and compiler characteristics.
 161 tinc_ATTRIBUTE(__malloc__)
 162 tinc_ATTRIBUTE(__nonnull__)
 163 tinc_ATTRIBUTE(__warn_unused_result__)
 164
 165 AC_CHECK_TYPES([struct ether_header, struct arphdr, struct ether_arp, struct ip, struct icmp, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 166   [#include "$srcdir/src/have.h"]
 167 )
 168
 169 dnl Checks for library functions.
 170 AC_CHECK_FUNCS([asprintf daemon fchmod flock fork gettimeofday mlockall putenv recvmmsg strsignal nanosleep unsetenv vsyslog devname fdevname],
 171   [], [], [#include "$srcdir/src/have.h"]
 172 )
 173
 174 AC_CHECK_FUNC(getopt_long, [getopt=true; AC_DEFINE(HAVE_GETOPT_LONG, 1, [getopt_long()])], [getopt=false])
 175 AM_CONDITIONAL(GETOPT, test "$getopt" = true)
 176
 177 AC_CHECK_DECLS([res_init], [AC_CHECK_LIB(resolv, res_init)], [], [
 178   #include <netinet/in.h>
 179   #include <resolv.h>
 180 ])
 181
 182 dnl Operating system specific checks
 183 case $host_os in
 184   *linux*)
 185     AC_CHECK_HEADERS([linux/if_tun.h],
 186       [], [AC_MSG_ERROR([Required header file missng])], [#include "$srcdir/src/have.h"]
 187     )
 188   ;;
 189   *bsd*|*dragonfly*|*darwin*)
 190     AC_CHECK_HEADERS([net/if_tun.h net/if_utun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h],
 191       [], [], [#include "$srcdir/src/have.h"]
 192     )
 193   ;;
 194   *solaris*)
 195     AC_CHECK_FUNC(socket, [], [AC_CHECK_LIB(socket, connect)])
 196   ;;
 197   *)
 198   ;;
 199 esac
 200
 201 AC_CACHE_SAVE
 202
 203 AC_ARG_ENABLE(legacy-protocol,
 204   AS_HELP_STRING([--disable-legacy-protocol], [disable support for the legacy (tinc 1.0) protocol]),
 205   [ AS_IF([test "x$enable_legacy_protocol" = "xno"],
 206     [ AC_DEFINE(DISABLE_LEGACY, 1, [Disable support for the legacy (tinc 1.0) protocol]) ])
 207   ]
 208 )
 209
 210 dnl These are defined in files in m4/
 211
 212 dnl AC_ARG_WITH(libgcrypt, AS_HELP_STRING([--with-libgcrypt], [enable use of libgcrypt instead of OpenSSL])], [])
 213 dnl AC_ARG_WITH(openssl, AS_HELP_STRING([--without-openssl], [disable support for OpenSSL])], [])
 214
 215 tinc_CURSES
 216 tinc_READLINE
 217 tinc_ZLIB
 218 tinc_LZO
 219 tinc_LZ4
 220
 221 AS_IF([test "x$enable_legacy_protocol" != "xno"],
 222       [AS_IF([test -n "$with_libgcrypt"],
 223              [gcrypt=true; tinc_LIBGCRYPT],
 224              [openssl=true; tinc_OPENSSL])
 225       ]
 226 )
 227
 228 AM_CONDITIONAL(OPENSSL, test -n "$openssl")
 229 AM_CONDITIONAL(GCRYPT, test -n "$gcrypt")
 230
 231 tinc_MINIUPNPC
 232 AM_CONDITIONAL(MINIUPNPC, test "x$enable_miniupnpc" = "xyes")
 233
 234 dnl Check if support for jumbograms is requested
 235 AC_ARG_ENABLE(jumbograms,
 236   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 237   [ AS_IF([test "x$enable_jumbograms" = "xyes"],
 238       [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ])
 239   ]
 240 )
 241
 242 dnl Compiler hardening flags
 243 dnl No -fstack-protector-all because it doesn't work on all platforms or architectures.
 244
 245 AX_CFLAGS_WARN_ALL(CFLAGS)
 246
 247 AC_ARG_ENABLE([hardening], AS_HELP_STRING([--disable-hardening], [disable compiler and linker hardening flags]))
 248 AS_IF([test "x$enable_hardening" != "xno"],
 249   [AX_CHECK_COMPILE_FLAG([-D_FORTIFY_SOURCE=2], [CPPFLAGS="$CPPFLAGS -D_FORTIFY_SOURCE=2"])
 250    AX_CHECK_COMPILE_FLAG([-fwrapv], [CPPFLAGS="$CPPFLAGS -fwrapv"],
 251    AX_CHECK_COMPILE_FLAG([-fno-strict-overflow], [CPPFLAGS="$CPPFLAGS -fno-strict-overflow"]))
 252    case $host_os in
 253      *mingw*)
 254        AX_CHECK_LINK_FLAG([-Wl,--dynamicbase], [LDFLAGS="$LDFLAGS -Wl,--dynamicbase"])
 255        AX_CHECK_LINK_FLAG([-Wl,--nxcompat], [LDFLAGS="$LDFLAGS -Wl,--nxcompat"])
 256        AX_CHECK_LINK_FLAG([-lssp], [LIBS="$LIBS -lssp"])
 257        ;;
 258      *)
 259        AX_CHECK_COMPILE_FLAG([-fPIE], [CPPFLAGS="$CPPFLAGS -fPIE"])
 260        AX_CHECK_LINK_FLAG([-pie], [LDFLAGS="$LDFLAGS -pie"])
 261        ;;
 262    esac
 263    AX_CHECK_LINK_FLAG([-Wl,-z,relro], [LDFLAGS="$LDFLAGS -Wl,-z,relro"])
 264    AX_CHECK_LINK_FLAG([-Wl,-z,now], [LDFLAGS="$LDFLAGS -Wl,-z,now"])
 265    AX_CHECK_COMPILE_FLAG([-W -Wextra -pedantic -Wreturn-type -Wold-style-definition -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wbad-function-cast -Wwrite-strings -fdiagnostics-show-option -fstrict-aliasing -Wmissing-noreturn],
 266      [CPPFLAGS="$CPPFLAGS -W -Wextra -pedantic -Wreturn-type -Wold-style-definition -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wredundant-decls -Wbad-function-cast -Wwrite-strings -fdiagnostics-show-option -fstrict-aliasing -Wmissing-noreturn"])
 267   ]
 268 );
 269
 270 dnl Ensure runstatedir is set if we are using a version of autoconf that does not support it
 271 if test "x$runstatedir" = "x"; then
 272   AC_SUBST([runstatedir], ['${localstatedir}/run'])
 273 fi
 274
 275 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile test/Makefile test/testlib.sh systemd/Makefile bash_completion.d/Makefile])
 276
 277 AC_OUTPUT