tinc-vpn.org Git - tinc/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_PREREQ(2.61)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([src/tincd.c])
   6 AM_INIT_AUTOMAKE(tinc, 1.0.13+git)
   7 AC_CONFIG_HEADERS([config.h])
   8 AM_MAINTAINER_MODE
   9
  10 # Enable GNU extensions.
  11 # Define this here, not in acconfig's @TOP@ section, since definitions
  12 # in the latter don't make it into the configure-time tests.
  13 AC_GNU_SOURCE
  14 AC_DEFINE([__USE_BSD], 1, [Enable BSD extensions])
  15
  16 ALL_LINGUAS="nl"
  17
  18 dnl Checks for programs.
  19 AC_PROG_CC_C99
  20 AC_PROG_CPP
  21 AC_PROG_INSTALL
  22 AC_PROG_LN_S
  23 AC_PROG_RANLIB
  24
  25 dnl Check and set OS
  26
  27 AC_CANONICAL_HOST
  28
  29 case $host_os in
  30   *linux*)
  31     AC_DEFINE(HAVE_LINUX, 1, [Linux])
  32     [ rm -f src/device.c; ln -sf linux/device.c src/device.c ]
  33   ;;
  34   *freebsd*)
  35     AC_DEFINE(HAVE_FREEBSD, 1, [FreeBSD])
  36     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  37   ;;
  38   *darwin*)
  39     AC_DEFINE(HAVE_DARWIN, 1, [Darwin (MacOS/X)])
  40     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  41   ;;
  42   *solaris*)
  43     AC_DEFINE(HAVE_SOLARIS, 1, [Solaris/SunOS])
  44     [ rm -f src/device.c; ln -sf solaris/device.c src/device.c ]
  45   ;;
  46   *openbsd*)
  47     AC_DEFINE(HAVE_OPENBSD, 1, [OpenBSD])
  48     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  49   ;;
  50   *netbsd*)
  51     AC_DEFINE(HAVE_NETBSD, 1, [NetBSD])
  52     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  53   ;;
  54   *dragonfly*)
  55     AC_DEFINE(HAVE_DRAGONFLY, 1, [DragonFly])
  56     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  57   ;;
  58   *bsd*)
  59     AC_MSG_WARN("Unknown BSD variant, tinc might not compile or work!")
  60     AC_DEFINE(HAVE_BSD, 1, [Unknown BSD variant])
  61     [ rm -f src/device.c; ln -sf bsd/device.c src/device.c ]
  62   ;;
  63   *cygwin*)
  64     AC_DEFINE(HAVE_CYGWIN, 1, [Cygwin])
  65     [ rm -f src/device.c; ln -sf cygwin/device.c src/device.c ]
  66   ;;
  67   *mingw*)
  68     AC_DEFINE(HAVE_MINGW, 1, [MinGW])
  69     [ rm -f src/device.c; cp -f src/mingw/device.c src/device.c ]
  70     LIBS="$LIBS -lws2_32 -lgdi32 -lcrypt32"
  71   ;;
  72   *)
  73     AC_MSG_ERROR("Unknown operating system.")
  74   ;;
  75 esac
  76
  77 AC_ARG_ENABLE(tunemu,
  78   AS_HELP_STRING([--enable-tunemu], [enable support for the tunemu driver]),
  79   [ AC_DEFINE(ENABLE_TUNEMU, 1, [Support for tunemu])
  80     tunemu=true
  81   ]
  82 )
  83
  84 AC_ARG_WITH(windows2000,
  85   AS_HELP_STRING([--with-windows2000], [compile with support for Windows 2000. This disables support for tunneling over existing IPv6 networks.]),
  86   [AC_DEFINE(WITH_WINDOWS2000, 1, [Compile with support for Windows 2000])]
  87 )
  88
  89 AM_CONDITIONAL(TUNEMU, test "$tunemu" = true)
  90
  91 AC_CACHE_SAVE
  92
  93 if test -d /sw/include ; then
  94   CPPFLAGS="$CPPFLAGS -I/sw/include"
  95 fi
  96 if test -d /sw/lib ; then
  97   LIBS="$LIBS -L/sw/lib"
  98 fi
  99
 100 dnl Checks for libraries.
 101
 102 dnl Checks for header files.
 103 dnl We do this in multiple stages, because unlike Linux all the other operating systems really suck and don't include their own dependencies.
 104
 105 AC_HEADER_STDC
 106 AC_CHECK_HEADERS([stdbool.h syslog.h sys/file.h sys/ioctl.h sys/mman.h sys/param.h sys/resource.h sys/socket.h sys/time.h sys/uio.h sys/wait.h netdb.h arpa/inet.h dirent.h])
 107 AC_CHECK_HEADERS([net/if.h net/if_types.h linux/if_tun.h net/if_tun.h net/tun/if_tun.h net/if_tap.h net/tap/if_tap.h net/ethernet.h net/if_arp.h netinet/in_systm.h netinet/in.h netinet/in6.h],
 108   [], [], [#include "have.h"]
 109 )
 110 AC_CHECK_HEADERS([netinet/if_ether.h netinet/ip.h netinet/ip6.h],
 111   [], [], [#include "have.h"]
 112 )
 113 AC_CHECK_HEADERS([netinet/tcp.h netinet/ip_icmp.h netinet/icmp6.h],
 114   [], [], [#include "have.h"]
 115 )
 116
 117 dnl Checks for typedefs, structures, and compiler characteristics.
 118 AC_C_CONST
 119 AC_C_VOLATILE
 120 AC_TYPE_PID_T
 121 AC_TYPE_SIZE_T
 122 AC_HEADER_TIME
 123 AC_STRUCT_TM
 124
 125 tinc_ATTRIBUTE(__malloc__)
 126
 127 AC_CHECK_TYPES([socklen_t, struct ether_header, struct arphdr, struct ether_arp, struct in_addr, struct addrinfo, struct ip, struct icmp, struct in6_addr, struct sockaddr_in6, struct ip6_hdr, struct icmp6_hdr, struct nd_neighbor_solicit, struct nd_opt_hdr], , ,
 128   [#include "have.h"]
 129 )
 130
 131 dnl Checks for library functions.
 132 AC_FUNC_MEMCMP
 133 AC_FUNC_ALLOCA
 134 AC_TYPE_SIGNAL
 135 AC_CHECK_FUNCS([asprintf daemon fchmod flock ftime fork get_current_dir_name gettimeofday mlockall putenv random select strdup strerror strsignal strtol system unsetenv usleep vsyslog writev],
 136   [], [], [#include "have.h"]
 137 )
 138 AC_FUNC_MALLOC
 139 AC_FUNC_REALLOC
 140
 141 dnl Support for SunOS
 142
 143 AC_CHECK_FUNC(socket, [], [
 144   AC_CHECK_LIB(socket, connect)
 145 ])
 146 AC_CHECK_FUNC(gethostbyname, [], [
 147   AC_CHECK_LIB(nsl, gethostbyname)
 148 ])
 149
 150 AC_CHECK_DECLS([freeaddrinfo, gai_strerror, getaddrinfo, getnameinfo],
 151   [], [], [#include "have.h"]
 152 )
 153
 154 AC_CACHE_SAVE
 155
 156 dnl These are defined in files in m4/
 157
 158 tinc_OPENSSL
 159 tinc_ZLIB
 160 tinc_LZO
 161
 162 dnl Check if support for jumbograms is requested
 163 AC_ARG_ENABLE(jumbograms,
 164   AS_HELP_STRING([--enable-jumbograms], [enable support for jumbograms (packets up to 9000 bytes)]),
 165   [ AC_DEFINE(ENABLE_JUMBOGRAMS, 1, [Support for jumbograms (packets up to 9000 bytes)]) ]
 166 )
 167
 168 AC_SUBST(INCLUDES)
 169
 170 AC_CONFIG_FILES([Makefile src/Makefile doc/Makefile lib/Makefile m4/Makefile])
 171
 172 AC_OUTPUT